Mehrwertsteuer in Excel berechnen
In Excel berechnen Sie die Mehrwertsteuer mit einfachen Formeln: =A2*1,19 rechnet Netto in Brutto um, =A2/1,19 Brutto in Netto und =RUNDEN(A2*19%;2) liefert den Steuerbetrag auf den Cent genau. Die Formeln funktionieren genauso in Google Sheets und LibreOffice Calc.
Das Wichtigste in Kürze
- Brutto:
=RUNDEN(A2*1,19;2)· Netto:=RUNDEN(A2/1,19;2)· Steuer aus Brutto:=A2-RUNDEN(A2/1,19;2) - Steuersatz in eine eigene Zelle schreiben und absolut beziehen (
$F$1), statt 19 % fest in jede Formel einzutragen. - Immer mit
RUNDEN()arbeiten – die Zellformatierung versteckt nur Nachkommastellen, rechnet aber mit ihnen weiter. - Für Rechnungen mit 7 % und 19 %: Netto je Satz mit
SUMMEWENNsummieren.
Inhalt
Die Grundformeln für Excel
Annahme: Der Ausgangsbetrag steht in Zelle A2, der Steuersatz als Prozentwert (19 %) in Zelle B2.
| Aufgabe | Formel (deutsches Excel) | Ergebnis bei 1.234,56 € |
|---|---|---|
| Netto → Brutto | =RUNDEN(A2*(1+B2);2) | 1.469,13 € |
| Steuer aus Netto | =RUNDEN(A2*B2;2) | 234,57 € |
| Brutto → Netto | =RUNDEN(A2/(1+B2);2) | 1.037,45 € |
| Steuer aus Brutto | =A2-RUNDEN(A2/(1+B2);2) | 197,11 € |
| Steuersatz ermitteln | =Brutto/Netto-1 (als % formatieren) | 19 % |
Die Mathematik hinter den Formeln erklären Mehrwertsteuer berechnen und die Übersicht der Mehrwertsteuer-Faktoren. Schneller für Einzelbeträge ist der Mehrwertsteuer-Rechner.
Steuersatz als Zelle statt fester Zahl
Schreiben Sie den Satz einmal in eine Zelle, etwa F1 = 19 %, und verweisen Sie mit $F$1 darauf: =RUNDEN(A2*(1+$F$1);2). Die Dollarzeichen sorgen dafür, dass der Bezug beim Herunterziehen der Formel nicht verrutscht. Ändert sich der Steuersatz, passen Sie nur eine Zelle an.
Prozent oder Zahl? Tragen Sie „19 %“ ein, speichert Excel den Wert 0,19. Tragen Sie „19“ ein, müssen Sie in der Formel durch 100 teilen: =A2*(1+B2/100). Mischen Sie beide Varianten nicht in einer Tabelle.
Vorlage: Rechnung mit 7 % und 19 %
Für Rechnungen mit Positionen zu unterschiedlichen Sätzen legen Sie je Zeile eine Spalte für den Steuersatz an:
| Spalte | Inhalt | Formel in Zeile 2 |
|---|---|---|
| A | Bezeichnung | – |
| B | Menge | – |
| C | Einzelpreis netto | – |
| D | Steuersatz (19 % oder 7 %) | – |
| E | Positionsbetrag netto | =RUNDEN(B2*C2;2) |
Darunter folgt die Zusammenfassung je Steuersatz – so verlangt es § 14 Abs. 4 Nr. 8 UStG:
| Zeile | Formel |
|---|---|
| Netto 19 % | =SUMMEWENN(D2:D20;19%;E2:E20) |
| USt. 19 % | =RUNDEN(SUMMEWENN(D2:D20;19%;E2:E20)*19%;2) |
| Netto 7 % | =SUMMEWENN(D2:D20;7%;E2:E20) |
| USt. 7 % | =RUNDEN(SUMMEWENN(D2:D20;7%;E2:E20)*7%;2) |
| Gesamt brutto | Summe der vier Zeilen darüber |
Durchgerechnetes Beispiel
Positionen: 3 × 12,50 € (19 %), 1 × 249,90 € (19 %) und 2 × 8,90 € (7 %). Ergebnis: Netto 19 % = 287,40 €, USt. 19 % = 54,61 €; Netto 7 % = 17,80 €, USt. 7 % = 1,25 €; Gesamt brutto 361,06 €. Den getrennten Ausweis erklärt der Mischsatz-Rechner, die übrigen Pflichtangaben stehen unter Pflichtangaben auf Rechnungen.
Beachten Sie: Ab 2027 bzw. 2028 müssen Rechnungen zwischen inländischen Unternehmen schrittweise als strukturierte E-Rechnung ausgestellt werden. Eine Excel-Tabelle oder ein daraus erzeugtes PDF erfüllt das nicht; Excel bleibt dann ein Kalkulationswerkzeug. Details: E-Rechnungspflicht.
Google Sheets und LibreOffice
Google Sheets mit deutscher Spracheinstellung versteht dieselben Funktionsnamen (RUNDEN, SUMMEWENN) und Semikolons. Bei englischer Einstellung lauten die Formeln =ROUND(A2*1.19,2) und =SUMIF(D2:D20,0.19,E2:E20) – mit Punkt als Dezimaltrennzeichen. LibreOffice Calc verhält sich wie das deutsche Excel.
Typische Fehler in Tabellen
- Ohne RUNDEN gerechnet: Excel zeigt 54,61 € an, rechnet aber mit 54,606 weiter. Summen weichen dann um Cent von der Rechnung ab. Hintergrund: Mehrwertsteuer runden.
- Mit 0,81 multipliziert:
=A2*0,81zieht 19 % vom Brutto ab und ist falsch. Richtig:=A2/1,19. - Relativer statt absoluter Bezug: Ohne
$verschiebt sich der Verweis auf die Satz-Zelle beim Kopieren und ergibt 0 oder falsche Werte. - Zahlen als Text: Aus Bankexporten importierte Beträge mit Punkt als Dezimaltrenner werden oft als Text erkannt. Prüfen Sie mit
=ISTZAHL(A2). - Steuersatz als SUMMEWENN-Kriterium: Steht in Spalte D „19“ statt „19 %“, findet das Kriterium
19%nichts. Kriterium und Zellinhalt müssen gleich formatiert sein.
Vorsteuer aus vielen Belegen summieren
Für die Voranmeldung tragen Sie Belege mit Bruttobetrag (Spalte B) und Satz (Spalte C) ein und berechnen die Vorsteuer mit =B2-RUNDEN(B2/(1+C2);2). Die Summe je Satz liefert =SUMMEWENN(C:C;19%;D:D). Ein fertiges Rechenbeispiel finden Sie beim Vorsteuer-Rechner; den Weg zur Zahllast unter Zahllast berechnen.
Häufige Fragen
Wie lautet die Excel-Formel für 19 % Mehrwertsteuer?
Für den Bruttobetrag =RUNDEN(A2*1,19;2), für den Steuerbetrag aus Netto =RUNDEN(A2*0,19;2).
Wie rechne ich in Excel die Mehrwertsteuer aus dem Bruttobetrag heraus?
Mit =RUNDEN(A2/1,19;2) erhalten Sie den Nettobetrag; die Steuer ist =A2-RUNDEN(A2/1,19;2).
Warum stimmt meine Excel-Summe nicht mit der Rechnung überein?
Meist fehlt RUNDEN(). Die Formatierung blendet Nachkommastellen nur aus, Excel rechnet mit dem ungerundeten Wert weiter.
Funktionieren die Formeln in Google Sheets?
Ja. Bei deutscher Spracheinstellung identisch, bei englischer mit ROUND, SUMIF, Komma als Trenner und Punkt als Dezimalzeichen.
Quellen
- Microsoft Support: Funktionen RUNDEN und SUMMEWENN
- § 14 Abs. 4 Nr. 7 und 8 UStG (Entgelt und Steuerbetrag je Steuersatz)
- § 14 Abs. 1 und § 27 Abs. 38 UStG (E-Rechnung und Übergangsregeln)